Versión en video (13:32 min):

Pascal

10. Tipos de datos numéricos: enteros y reales

10.1. Números enteros

Como hemos visto, se puede emplear la palabra "integer" para indicar que una variable se usará para almacenar un número entero. Pero además podemos afinar si queremos que este número entero permita almacenar números muy grandes o bien podemos optimizar para que ocupe poco espacio.

Ciertas versiones de Pascal, como Turbo Pascal y FreePascal, permiten escoger entre varios tipos de números enteros, de modo que podemos elegir el más adecuado en caso de que queramos no desperdiciar espacio o de que prefiramos almacenar datos de gran tamaño. Estos son los tipos más habituales:

Así, un "byte" sería un tipo de datos adecuado para la edad de una persona (que no puede ser negativa, ni podemos esperar que necesite valores por encima de 255), y un "integer" no sería adecuado para la población de un país (porque no necesitaríamos datos negativos, y claramente puede ser un número por encima de 32.767). No todos los tipos de datos estarán disponibles en todos los sistemas. Por ejemplo el tipo "comp" puede no estar en sistemas antiguos, cuyo procesador no tenga un coprocesador matemático (Intel 386 y anteriores, por ejemplo).

Un ejemplo, que pidiese a una persona su edad en años (para lo que bastaría un "byte") y que calculase una aproximación de su edad en meses, multiplicando por 12 (para lo que parece adecuado un "word") podría ser:

(* Enteros sin signo: byte y word *)

program Enteros1;

var
  edad: byte;
  meses: word;

begin
  write('Dime tu edad: ');
  readLn(edad);
  meses := edad * 12;
  writeLn('Aproximadamente tienes ', meses, ' meses');
end.

(* Ejemplo de ejecucion:
Dime tu edad: 20
Aproximadamente tienes 240 meses
*)

10.2. Números reales

En general, en la mayoría de cálculos necesitaremos tener en cuenta las cifras decimales, no siempre podremos trabajar con números enteros. Para esos casos, el lenguaje Pascal nos permite usar un tipo llamado "real".

Por ejemplo, si queremos convertir de centímetros a metros, tendremos que dividir entre 100, de modo que obtendremos cifras decimales (a no ser que deseemos perder precisión y usemos "div"), y necesitaremos emplear números reales:

(* Numeros reales, primer contacto *)

program Reales1;

var
  centimetros, metros: real;

begin
  write('Dime la longitud, en centimetros: ');
  readLn(centimetros);
  metros := centimetros / 100;
  writeLn('Equivalen a ', metros, ' metros');
end.

(* Ejemplo de ejecucion:
Dime la longitud, en centimetros: 32.8
Equivalen a  3.28000000000000E-001 metros
*)

A la hora de introducir datos, debemos usar un punto para separar la parte entera de la parte fraccionaria, no una coma. De igual modo, los resultados se mostrarán también con punto. Pero además el resultado es poco legible, porque en Pascal, los números reales se muestran en notación científica a no ser que indiquemos lo contrario. Un número como 3e2 o 3E+2 equivaldría a 3·10², es decir, 3·100 = 300, mientras que 3e-2 o 3.0E-002 indicaría que el resultado es 3·10^-2, es decir, 3x0.01 = 0.03

Podemos hacer que resulte más legible si indicamos cuantas cifras totales y cuantas cifras decimales queremos que se muestren, haciendo:

write(numero:cifrasTotales:cifrasDecimales);

De modo que el ejemplo anterior se podría reescribir de la siguiente forma, para que mostrase 4 cifras decimales y 5 (o más) cifras en total:

(* Numeros reales y formato en pantalla *)

program Reales2;

var
  centimetros, metros: real;

begin
  write('Dime la longitud, en centimetros: ');
  readLn(centimetros);
  metros := centimetros / 100;
  writeLn('Equivalen a ', metros:5:4, ' metros');
end.

(* Ejemplo de ejecucion:
Dime la longitud, en centimetros: 32.8
Equivalen a 0.3280 metros
*)

Pero Turbo Pascal y FreePascal nos permiten emplear varios tipos de datos reales, con mayor o menor precisión y que ocupan más o menos espacio, para adecuarlos a nuestras necesidades:

En todos estos datos, la precisión se mide en "cifras significativas", que son las cifras distintas de cero que hay al principio o al final del número: un número como 0.0002 tiene una cifra significativa, 33 tiene 2 cifras significativas, al igual que 33000, mientras que 33001 tiene 6 cifras significativas.

10.3. Algunas funciones matemáticas

En el lenguaje Pascal podemos encontrar ciertas funciones matemáticas incorporadas, que nos permitirán resolver problemas matemáticos de mayor complejidad que lo que podemos conseguir sólo con los operadores aritméticos básicos. Por ejemplo, "sqrt" nos sirve para calcular una raíz cuadrada:

(* Raiz cuadrada *)

program Raiz;

var
  n: real;

begin
  write('Dime un numero: ');
  readLn(n);
  writeLn('Su raiz es ', sqrt(n):2:1);
end.

(* Ejemplo de ejecucion:
Dime un numero: 4
Su raiz es 2.0
*)

De igual modo, existe otra función llamada "sqr", que calcula el cuadrado de un número. El valor de "sqr(n)" será el mismo que el de "n*n".

También podemos obtener números al azar: random(x) nos da un número entre 0 (incluido) y x (no incluido). Antes será necesario usar "randomize", para dar un valor inicial a la secuencia de números al azar, tomado a partir del valor actual del reloj interno del ordenador:

(* Numero al azar entre 0 y 9 *)

program Azar;

begin
  Randomize;
  writeLn('Numero al azar: ', random(10) );
end.

(* Ejemplo de ejecucion:
Numero al azar: 6
*)

Si debemos buscar un número entre dos valores cualesquiera, deberemos sumar una cantidad al valor generado por random. Por ejemplo, para obtener un número entre 10 y 30 usaríamos 10+random(21).

Si has estudiado trigonometría, quizá te alegre saber que puedes calcular senos (con la función "sin") y cosenos (con "cos"). Ambos datos esperan que entre paréntesis se les indique el ángulo, pero medido en radianes, no en grados (tampoco es un grave problema, la equivalencia es que 180 grados = PI radianes):

(* Coseno de 45 grados *)

program Coseno;

var
  pi, angulo, resultado: real;

begin
  pi := 3.1416;
  angulo := pi / 4; (* 45 grados = PI / 4 radianes *)
  resultado := cos(angulo);
  writeLn('El coseno de 45 grados es ', resultado:4:3);
end.

(* Ejemplo de ejecucion:
El coseno de 45 grados es 0.707
*)

Y si has trabajado con logaritmos y exponenciales, tendrás a tu disposición ln(x) para calcular logaritmos neperianos y exp(x) para calcular el valor de "e elevado a x":

(* Ejemplo de exponencial y logaritmo *)

program ExponencialYLogaritmo;

begin
  write('e elevado al cuadrado es: ');
  writeLn( exp(2) );
  write('El logaritmo de 10 es: ');
  writeLn( ln(10) );
end.

(* Ejemplo de ejecucion:
Dime la base: 2
Dime el exponente: 3
Su potencia es: 8.0
*)

En Pascal estándar no hay forma directa de elevar un número cualquiera a otro, pero podemos imitarlo con "exp" y "ln", así:

(* Potencia: un numero elevado a otro *)

program Potencia;

var
  base, exponente: real;

begin
  write('Dime la base: ');
  readLn(base);
  write('Dime el exponente: ');
  readLn(exponente);
  writeLn('Su potencia es: ',
     Exp(exponente * Ln(base)) );
end.

(* Ejemplo de ejecucion:
Dime la base: 2
Dime el exponente: 3
Su potencia es: 8.0
*)

(Veremos una forma más compacta de calcular potencias cuando descubramos qué son las "unidades")

Como referencia algo más detallada, éstas son las funciones matemáticas incluídas en Pascal:

• Abs: valor absoluto de un número.
• Sin: seno de un cierto ángulo dado en radianes.
• Cos: coseno, análogo.
• ArcTan: arco tangente. No existe función para la tangente, que podemos calcular como sin(x)/cos(x).
• Round: redondea un número real al entero más cercano.
• Trunc: trunca los decimales de un número real para convertirlo en entero.
• Int: igual que trunc, pero el resultado sigue siendo un número real.
• Sqr: eleva un número al cuadrado.
• Sqrt: halla la raíz cuadrada de un número.
• Exp: exponencial en base e, es decir, eleva un número a e.
• Ln: calcula el logaritmo neperiano (base e) de un número.
• Odd: devuelve TRUE si un número es impar.

Ejercicios propuestos

Ej.10.01: Crea un programa que te pregunte dos números del 1 al 10 y escriba su suma. Escoge un tipo de datos que no desperdicie mucho espacio.

Ej.10.02: Pide al usuario dos números reales y muestra en pantalla el resultado de su división, con dos cifras decimales.

Ej.10.03: Crea un programa que te pida un número y calcule su raíz cuarta (la raíz cuadrada de su raíz cuadrada).